UCOZ Реклама
5d кинотеатр 3д домашние кинотеатры, бизнес идеи для начинающих

Урок N 28

МАССИВЫ

Числовой массив

С понятием "массив" приходится сталкиваться при решении науч-

но-технических и экономических задач обработки совокупностей

большого количества значений.

Массив - это множество однотипных элементов, объединённых общим

именем и занимающих в компьютере определённую область памяти.

Количество элементов в массиве всегда конечно.

В общем случае массив - это структурированный тип данных, состоя-

щий из фиксированного числа элементов, имеющих один и тот же тип.

Название регулярный тип (или ряды) массивы получили за то, что в

них объединены однотипные (логически однородные) элементы, упоря-

доченные (урегулированные) по индексам, определяющим положение

каждого элемента в массиве.

В качестве элементов массива можно использовать любой тип дан-

ных, поэтому вполне правомерно существование массивов записей,

массивов указателей, массивов строк, массивов массивов и т.д.

Элементами массива могут быть данные любого типа, включая струк-

турированные.

Тип элементов массива называется базовым. Особенностью языка

Паскаль является то, что число элементов массива фиксируется при

описании и в процессе выполнения программы не меняется.

Элементы, образующие массив, упорядочены таким образом, что каж-

дому элементу соответствует совокупность номеров (индексов), оп-

ределяющих его местоположение в общей последовательности. Доступ

к каждому отдельному элементу осуществляется путем индексирования

элементов массива. Индексы представляют собой выражения любого

скалярного типа (чаще целого), кроме вещественного.

Тип индекса определяет границы изменения значений индекса. Для

описания массива предназначено словосочетание array of (массив из).

 

Одномерные массивы

Массивом называется совокупность данных, выполняющих аналогичные

функции, и обозначаемая одним именем. Если за каждым элементом

массива закреплен только один его порядковый номер, то такой мас-

сив называется линейным, или одномерным.

 

Массив в Бейсике

Описывать массив DIM A(N) - это значит предоставить < N >

свободных ячеек в памяти ЭВМ для массива с именем А.

Если описание массива отсутствует, то под одномерный

массив выделяется 10 ячеек памяти.

Каждый элемент массива в общем виде описывается как А(I), где

А - имя массива,

I - номер или индекс массива (0<=I<= N, но практически

употребляется 1<=I<=N)

A(I) - значение элемента массива.

Задачи на числовые массивы

Класификация задач на массивы

Пример 1: Ввод 10 элементов массива с клавиатуры
и вывод их на экран.

CLS
DIM A(10)
FOR i = 1 TO 10
INPUT A(i)
PRINT A(i)
NEXT i
END

Пример 2: Ввод 10 элементов массива с помощью датчика случайных чисел
и вывод их на экран.

CLS
DIM A(10)
FOR i = 1 TO 10
A(i) = INT(RND * 20)
PRINT A(i)
NEXT i
END

Пример 3: Вычисление среднего арифметического массива,
состоящего из N элементов.

CLS
INPUT "Введите число элементов массива N=", N
DIM A(N)
FOR i = 1 TO N
A(i) = INT(RND * 20)
s = s + A(i)
PRINT A(i)
NEXT i
PRINT "Среднее арифметическое Sa ="; s / N
END

Пример 4: Вывод первого и последнего из 15 элементов массива.

CLS
DIM A(15)
FOR i = 1 TO 15
A(i) = INT(RND * 20)
PRINT A(i)
NEXT i
PRINT "Первый"; A(1)
PRINT "Последний"; A(15)
END

Пример 5: Вывод элементов массива, состоящего из 10 элементов,
с чётными и нечётными номерами.

CLS
DIM A(10)
FOR i = 1 TO 10
A(i) = INT(RND * 20)
PRINT A(i)
NEXT i
PRINT "Элементы с нечётными номерами"
FOR k = 1 TO 10 STEP 2
PRINT A(k)
NEXT k
PRINT
PRINT "Элементы с чётными номерами"
FOR k = 1 TO 10 STEP 2
PRINT A(k + 1)
NEXT k
END

Пример 6: Вывести минимальный и максимальный элементы массива,
состоящего из 10 целых чисел.

CLS
DIM a(10)
FOR i = 1 TO 10
a(i) = INT(RND * 70)
PRINT a(i)
NEXT i
m = a(1)
n = a(1)
FOR z = 1 TO 10
IF a(z) > m THEN m = a(z)
NEXT z
FOR j = 1 TO 10
IF a(j) < n THEN n = a(j)
NEXT j
PRINT "max", m
PRINT "min", n
END

Пример 7: Найти наибольший элемент числового массива
A = (a1, a2 , ..., aN ) и определить его номер.

CLS
INPUT "Ввести число элементов массива N = "; N
DIM A(N)
FOR i = 1 TO N ' Ввод массива А
PRINT "A("; i; ") = ";
INPUT A(i)
NEXT i
Amax = A(1): k = 1 ' Поиск максимального элемента
FOR i = 2 TO N
IF A(i) > Amax THEN Amax = A(i): k = i
NEXT i
PRINT "Наибольший элемент"; k; "-й"
PRINT "Его значение"; Amax
END

Пример 8: Вывод отрицательных элементов массива.
CLS
DIM A(10)
FOR I = 1 TO 10
INPUT A(I)
NEXT I
FOR I = 1 TO 10
IF A(I) < 0 THEN PRINT A(I)
NEXT I
END

Пример 9: Определить количество отрцательных элементов массива.

CLS
INPUT "Введите число элементов массива N=", N
DIM A(N)
FOR i = 1 TO N
INPUT "Ввод элементов массива с клавиатуры", A(N)
IF A(N) < 0 THEN k = k + 1
NEXT i
PRINT "Количество отрцательных элементов массива"; k
END

Пример 10: Определить, имеется ли в заданном целочисленном
массиве A(N) хотя бы одна пара совпадающих по значению чисел.

CLS
INPUT "N = ", N
DIM A(N) ' ввод массива А
FOR i = 1 TO N
PRINT "A(" ; i ; ") = " ;
INPUT A(i)
NEXT i
PRINT : PRINT "Массив А" ' вывод массива А
FOR i = 1 TO N
PRINT A(i) ;
NEXT i : PRINT
i = 1 : Flag = 0 ' поиск совпадающих чисел
WHILE (i <= N - 1) AND (Flag = 0)
j = i + 1
WHILE (j <= N) AND (Flag = 0)
IF A(i)=A(j) THEN Flag=1 ELSE j=j+1
WEND
i = i + 1
WEND
PRINT : PRINT "О т в е т :"
IF Flag = 1 THEN
PRINT "Есть совпадающие числа."
ELSE PRINT "Нет совпадающих чисел."
END IF
END

Пример 11: Сортировка массива по возрастанию.
Массив из 20 чисел задаётся с помошью генератора случайных чисел.

CLS
DIM a(20) AS INTEGER 'Объявляем массив для чисел
DIM i AS INTEGER 'счётчик
DIM j AS INTEGER 'счётчик
DIM b AS INTEGER 'хранит значение a(i) для передачи в a(j)
FOR i = 1 TO 20
a(i) = INT(RND * 30000)'числа положительные,
'отрицательные так -> a(i) = int(rnd*60000)-30000
NEXT i
'Выводим на экран массив в не отсортированном виде
FOR i = 1 TO 20
PRINT a(i),
NEXT i
FOR i = 1 TO 19
FOR j = i + 1 TO 20
IF a(i) > a(j) THEN
b = a(i)
a(i) = a(j)
a(j) = b
END IF
NEXT j
NEXT i
PRINT 'пустая строка
'Выводим на экран массив в отсортированном виде
FOR i = 1 TO 20
PRINT a(i),
NEXT i
END

Задачи на символьные массивы

Пример 12: Определите, является ли вводимое число или слово палиндромом
(перевёртышем, например, 1991 или kazak), или нет?

DEFLNG I-N
DEFSTR S
DIM mb(10000) AS LONG
CLS
INPUT "Введите натуральное число или слово"; s
s1 = s
FOR i = 1 TO LEN(s) / 2 'перевернули строку
sw = MID$(s1, i, 1)
MID$(s1, i, 1) = MID$(s1, LEN(s) - i + 1)
MID$(s1, LEN(s) - i + 1) = sw
NEXT i
IF s = s1 THEN
PRINT "ЭТО ЧИСЛО ИЛИ СЛОВО - ПАЛИНДРОМ"
ELSE
PRINT "ЭТО ЧИСЛО ИЛИ СЛОВО - НЕ ПАЛИНДРОМ"
END IF
END

Пример 13: Вывести первый и последний символы слова.

CLS
INPUT A$
PRINT LEFT$(A$, 1)
PRINT RIGHT$(A$, 1)
END

Пример 14: Вывести слово наоборот, т.е. с обратным порядком букв

CLS
ss$ = ""
INPUT ; s$
FOR i = LEN(s$) TO 1 STEP -1
ss$ = ss$ + MID$(s$, i, 1)
NEXT
PRINT , ss$
END

Пример 15: Определить количество слов в заданном тексте.

CLS
PRINT "Введите текст, отделяя слова пробелами."
PRINT "Если в тексте есть запятые, заключите его в кавычки."
INPUT Text$: PRINT
Number = 0: Flag = 0
FOR i = 1 TO LEN(Text$) 'цикл по буквам текста
Letter$ = MID$(Text$, i, 1) 'текущая буква текста
IF (Letter$ <> " ") AND (Flag = 0) THEN Number = Number + 1
IF (Letter$ = " ") THEN Flag = 0 ELSE Flag = 1
NEXT i
PRINT "О т в е т : количество слов в тексте равно "; Number
END

Пример 16: B заданном тексте одно заданное слово везде заменить на другое заданное слово

CLS
INPUT "Введите текст : " , Text$
INPUT "Какое слово заменить ? " , Slovo1$
INPUT "На какое слово заменить ? " , Slovo2$
PRINT : PRINT "О т в е т"
PRINT "Исходный текст : " ; Text$
DlinaText = LEN(Text$) : DlinaSlova = LEN(Slovo1$)
FOR i = 1 TO DlinaText-DlinaSlova+1
IF MID$(Text$, i, DlinaSlova) = Slovo1$ THEN
MID$(Text$, i) = Slovo2$ : i=i+DlinaSlova
END IF
NEXT i
PRINT "Новый текст : " ; Text$
END

Пример 17: Заданную последовательность слов переупорядочить в алфавитном порядке
(то есть выполнить лексикографическое упорядочение).

CLS
INPUT "Введите количество слов в тексте — ", NWords
DIM Words(NWords) AS STRING
FOR i = 1 TO NWords
PRINT i; "-ое слово " ; : INPUT Words(i)
NEXT i
FOR i = 1 TO NWords - 1 'лексикографическое упорядочение слов
FOR j = i + 1 TO NWords
IF Words(i) > Words(j) THEN SWAP Words(i), Words(j)
NEXT j
NEXT i
PRINT : PRINT "О т в е т"
PRINT "Лексикографически упорядоченный массив слов:"
FOR i = 1 TO NWords
PRINT Words(i); " " ;
NEXT i
PRINT
END

Задачи на двумерные массивы (матрицы)

Пример 18: В заданной целочисленной матрице A(N, M)
найти количество строк, содержащих нули.

CLS
INPUT "Количество строк - ", N
INPUT "Количество столбцов - ", M
DIM A(N, M)
FOR i = 1 TO N
FOR j = 1 TO M
PRINT "A(" ; i ; ", " ; j ; ") = " ;
INPUT A(i, j)
NEXT j
NEXT i : CLS
PRINT "Исходная матрица :" : PRINT
FOR i = 1 TO N
FOR j = 1 TO M
PRINT A(i, j) ;
NEXT j : PRINT
NEXT i : PRINT
K = 0
FOR i = 1 TO N 'цикл по всем строкам
j = 1 : Flag = 0
WHILE (j <= M) AND ( Flag = 0 ) 'цикл до нулевого элемента строки
IF A(i, j) = 0 THEN Flag = 1: K = K + 1 ELSE j = j + 1
WEND
NEXT i
PRINT "О т в е т : строк, содержащих нули, " ; K ; "."
END

Пример 19: Дана целочисленная матрица A(N, N).
Определить, имеются ли среди её элементов,
лежащих ниже главной диагонали, отрицательные числа.

CLS
INPUT "Количество строк и столбцов матрицы = ", N
DIM A(N, N)
FOR i = 1 TO N
FOR j = 1 TO N
PRINT "A(" ; i ; ", " ; j ; ") = " ;
INPUT A(i, j)
NEXT j
NEXT i
CLS : PRINT "Матрица А"
FOR i = 1 TO N
FOR j = 1 TO N
PRINT A(i, j);
NEXT j : PRINT
NEXT i
i = 2 : Flag = 0
WHILE (i < = N) AND (Flag = 0)
j = 1
WHILE (j < i ) AND (Flag = 0)
IF A(i, j) < 0 THEN Flag = 1 ELSE j = j + 1
WEND
i = i + 1
WEND
PRINT : PRINT "О т в е т :"
PRINT "Среди элементов матрицы, лежащих ниже главной диагонали, ";
IF Flag = 1 THEN
PRINT "есть отрицательные."
ELSE PRINT "нет отрицательных."
END IF
END

Пример 20: Дана целочисленная матрица A(N, M).
Определить, встречается ли заданное целое K среди
максимальных элементов столбцов этой матрицы.

CLS
INPUT "Введите целое K = ", K
PRINT "Введите целочисленную матрицу А"
INPUT "Количество строк - ", N
INPUT "Количество столбцов - ", M
DIM A(N, M)
FOR i = 1 TO N
FOR j = 1 TO M
PRINT "A(" ; i ; ", " ; j ; ") = " ;
INPUT A(i, j)
NEXT j
NEXT i : CLS
PRINT "Исходная матрица "
FOR i = 1 TO N
FOR j = 1 TO M
PRINT A(i, j);
NEXT j : PRINT
NEXT i : PRINT
Flag = 0 : j = 1
WHILE (j <= M) AND (Flag = 0) 'цикл по столбцам с прерыванием
JMax = A(1, j)
FOR i = 2 TO N 'цикл нахождения JMax
IF A(i, j) >

JMax THEN JMax = A(i, j)
NEXT i
IF K = JMax THEN Flag = 1 ELSE j = j + 1 'условие прерывания
WEND
PRINT "О т в е т : число"; K;
IF Flag = 1 THEN
PRINT "встречается";
ELSE PRINT "не встречается";
END IF
PRINT " среди максимальных элементов столбцов матрицы"
END

 

Массив в Паскале

<имя массива>:= array [<количество элементов>] of <тип переменной>;

Каждый элемент массива в общем виде описывается как А, где

А - имя массива,

I - номер или индекс массива (0<=I<=N, но практически

употребляется 1<=I<=N)

A - значение элемента массива.

 

Действия над массивами

Для работы с массивом как единым целым используется идентифика-

тор массива без указания индекса в квадратных скобках. Массив мо-

жет участвовать только в операциях отношения "равно", "не равно"

и в операторе присваивания. Массивы, участвующие в этих действи-

ях, должны быть идентичны по структуре, т. е. иметь одинаковые

типы индексов и одинаковые типы компонентов.

Например, если массивы А и В описаны как

var А, В: array[1..20] of real; то применение к ним допустимых

операций даст следующий результат:

 

Выражение Результат

 

А=В True, если значение каждого элемента массива А равно

соответствующему значению элемента массива В

 

А<>В True, если хотя бы одно значение элемента массива А

не равно значению соответствующего элемента массива В

 

А:=В Все значения элементов массива В присваиваются соответ-

ствующим элементам массива А. Значения элементов

массива В остаются неизменны.

 

Действия над элементами массива

После объявления массива каждый его элемент можно обработать,

указав идентификатор (имя) массива и индекс элемента в квадратных

скобках. Например, запись Mas[2], VectorZ[10] позволяет обратить-

ся ко второму элементу массива Mas и десятому элементу массива

VectorZ.

При работе с двумерным массивом указываются два индекса, с

n-мерным массивом - n индексов. Например, запись MatrU[4,4] дела-

ет доступным для обработки значение элемента, находящегося в чет-

вертой строке четвертого столбца массива MatrU.

Индексированные элементы массива называются индексированными пе-

ременными и могут быть использованы так же, как и простые пере-

менные. Например, они могут находиться в выражениях в качестве

операндов, использоваться в операторах for, while, repeat, вхо-

дить в качестве параметров в операторы Read, Readln, Write, Wri-

teln; им можно присваивать любые значения, соответствующие их ти-

пу.

 

Алгоритмы сортировки одномерных массивов

Сортировка - один из наиболее распространённых процессов совре-

менной обработки данных. Сортировкой называется распределение

элементов массива в соответствии с определёнными правилами. Нап-

ример, сортировка массива по возрастанию или убыванию его элемен-

тов.

Обменная сортировка (метод "пузырька").

Алгоритм начинается со сравнения 1-го и 2-го элементов массива.

Если 2-й элемент меньше 1-го, то они меняются местами. Этот про-

цесс повторяется для каждой пары соседних элементов массива, пока

все N элементов не будут обработаны. За один "проход" массива са-

мый большой элемент встанет на старшее (N-е) место. Далее алго-

ритм повторяется, причем на р-м "проходе" первые (N-p) элементов

сравниваются со своими правыми соседями. Если на очередном "про-

ходе" перестановок не было, то алгоритм свою работу закончил. Та-

ким образом, самые "легкие" элементы в процессе исполнения алго-

ритма постепенно "всплывают".

 

Сортировка вставками.

Вначале упорядочиваются два первых элемента массива. Они образу-

ют начальное упорядоченное множество S. Далее на каждом шаге бе-

рется следующий по порядку элемент и вставляется в уже упорядо-

ченное множество S так, чтобы слева от него все элементы были не

больше, а справа - не меньше обрабатываемого. Место для вставки

текущего элемента в упорядоченное множество S ищется методом де-

ления пополам. Алгоритм сортировки заканчивает свою работу, когда

элемент, стоящий на N-м месте, будет обработан. (Именно таким об-

разом игроки в бридж обычно упорядочивают свои карты).

 

Сортировка выбором.

Находится наибольший элемент в массиве из N элементов (пусть он

имеет номер р) и меняется местами с элементом, стоящим на N-м

месте, при условии, что N<>p. Из оставшихся (N-1) элементов снова

выделяется наибольший и меняется местами с элементом, стоящим на

(N-1)-м месте и т. д. Алгоритм заканчивает свою работу, когда

элементы, стоящие на 1-м и 2-м местах в массиве, будут упорядоче-

ны (для этого понадобится N-1 "проход" алгоритма). Аналогично

данный алгоритм можно применять и к наименьшим элементам.

 

Двумерные массивы

Двумерным называется массив, элемент которого зависит от его

местоположения в строке и в столбце. В общем виде элемент матрицы

обозначается как A(I,J), где А - имя массива,

I - индекс (номер) строки,

J - индекс (номер) столбца.

 

Описание матрицы на языке Бейсик

DIM A(I,J) - описать матрицу (двумерный массив) это значит пре-

доставить свободные ячейки в памяти ЭВМ для элементов данной мат-

рицы. В памяти ЭВМ элементы матрицы располагаются по строкам, по-

этому индекс строки изменяется медленнее, чем индекс столбца.

Прямоугольной называется матрица, в которой количество строк не равно количеству столбцов.

Квадратной называется матрица, в которой количество строк равно количеству столбцов.

Диагональной матрицей называется квадратная матрица, у которой все элементы, не находящиеся на главной диагонали, равны нулю:

Диагональная матрица

Диагональная матрица, все диагональные элементы которой равны 1, называется единичной.

 

Описание матрицы на языке Паскаль

Матрицу можно задать двумя способами:

 

I. <имя матрицы>: array [<количество строк>] of array [<количество

столбцов>] of <тип переменной>;

 

II. <имя матрицы>: array [<количество строк >,<количество столб-

цов>] оf <тип переменной>].

 

Соотношение индексов в квадратной матрице

I=J элементы матрицы расположены на главной

диагонали

I<J элементы матрицы расположены над главной

диагональю

I>J элементы матрицы расположены под главной

диагональю

I+J=N+I элементы матрицы расположены на побочной

диагонали (N - количество строк или

столбцов в квадратной матрице)

I+J<N+I элементы матрицы расположены над побочной

диагональю

I+J>N+I элементы матрицы расположены под побочной

диагональю.

 

Ниже приведены примеры задач с массивами на языке Turbo Pascal.

 

Пример 1. Ввод значений элементов массива с помощью генератора

случайных чисел и вывод их в строчку.

 

Примечание:

Для использования случайных чисел в TP используются операторы

random:real - генерирует случайные числа в диапазоне 0...0.99.

random(i:word):word - генерирует случайные числа в диапазоне

0...1.

randomize - изменение базы генератора случайных чисел.

 

program mas1;

var

a: array [1..10] of integer;

i: integer;

begin

randomize;

for i:=1 to 10 do

begin

a:=random(20);

write('a(', i, ')=', a, ' ')

end;

readln

end.

 

Пример 2. Составить программу заполнения одномерного массива, так

чтобы его i-ый элемент был равен a=(i*i+1)/sin(i).

 

program mas2;

var a: array [1..10] of real;

i: integer;

begin

for i:=1 to 10 do

begin

a:=(i*i+1)/sin(i);

writeln('a(', i, ')=', a, ' ');

end;

readln

end.

 

Пример 3. Составить программу определения количества элементов

одномерного массива, значение элементов которых меньше

заданного действительного числа t.

 

program mas3;

var a: array [1..10] of real;

i,k: integer; t:real;

begin

write('Введите число t=');

read(t);

k:=0;

for i:=1 to 10 do

begin

write('Введите значение элемента a(', i, ') = ');

readln(a);

if a<t then k:=k+1

end;

writeln('Ответ: Количество элементов, меньших заданного числа t,');

writeln('равно k=',k);

readln

end.

 

Пример 4. Нахождение среди значений элементов, находящихся на

главной диагонали матрицы, наибольшего и наименьшего.

 

program mas4;

var

a: array[1..10,1..10] of integer;

i,j,max,min: integer;

begin

for i:=1 to 10 do

for j:=1 to 10 do

begin

write('Введите значение элемента матрицы = ');

readln(a[i,j])

end;

max:=a[1,1];

min:=a[1,1];

for i:=1 to 10 do

begin

if a[i,i]>max

then

max:=a[i,i];

if a[i,i]<min

then

min:=a[i,i]

end;

writeln('Наибольшее значение = ', max);

writeln('Наименьшее значение = ', min);

readln

end.

 

Пример 5. Сортировка массива по возрастанию.

 

program SortingMax;

var i,j:integer;

r,q:real;

x:array [1..20] of real;

begin

writeln('Ведите массив, cостоящий из 20 чисел:');

for i:=1 to 20 do read(x);

for i:=1 to 19 do

for j:=i+1 to 20 do

if x>=x[j] then

begin

r:=x; x:=x[j]; x[j]:=r

end;

writeln('Сортировка массива по возрастанию произведена:');

for i:=1 to 20 do writeln(x);

writeln('Для выхода введите любое число.');

readln(q);

end.

Задачи

1. Составить программу суммирования значений элементов одномерного

массива, больших (или меньших) заданного действительного числа t.

2. Составить программу определения количества элементов одномерного

массива, значения элементов которых больше заданного действительного числа t.

3. Произведите сортировку элементов одномерного массива по убыванию.


Продолжение темы "Массивы"

1) МАССИВЫ 2

2) Алгоритмы обработки символьной информации.
Символьные массивы

3) Решение типовых задач на строковые массивы

4) Задачи на различные массивы

Возврат в оглавление

Hosted by uCoz